Script Snippets & Functions

This is a thread that people can use to share useful custom functions or scripts they have written that they feel the community would find useful.

Be sure to also explain what each does and how to use it.

INDEX

• MIN/MAX
• SWAP ITEMS
• ASSIGN SKILL - OBSOLETE: Give_Skill() does this for you now!
• CLEAR ENTRY - OBSOLETE: Use built in array.erase() function now.
• COUNT ITEMS
• REWARD ITEM
• RETURN STRING REMAINDER
• AUTO ZOOM IN
• AUTO ZOOM OUT
• CUSTOM INTERACT (For Free Movement)

To present code on this forum:
it's slightly different to the discord approach.

Here's a snapshot of how to use the three backticks on here. (seperate lines above/below the code).

produces this:

function min($num_array) begin
    if $num_array == null then
        print("Not a valid array");
        return false;
    end;
    $smallest = $num_array[0];
    for $num in $num_array do
        if $num < $smallest then
            $smallest = $num;
        end;
    end;
    return $smallest;
end;

MIN/MAX

These two functions will add the ability to scan an array and return either the smallest (min) or the largest (max) number.

To install, copy the following code into the Global Functions panel found in Game Configuration.

function min($num_array) begin
    if $num_array == null then
        print("Not a valid array");
        return false;
    end;
    $smallest = $num_array[0];
    for $num in $num_array do
        if $num < $smallest then
            $smallest = $num;
        end;
    end;
    return $smallest;
end;

function max($num_array) begin
    if $num_array == null then
        print("Not a valid array");
        return false;
    end;
    $largest = $num_array[0];
    for $num in $num_array do
        if $num > $largest then
            $largest = $num;
        end;
    end;
    return $largest;
end;

To use, simply pass in an array consisting of numerical values into the function within a script and it will return the smallest/largest number into a variable.

Example:

CLEAR ENTRY

This function will allow you to scan through a provided array for a provided entry, and if it finds such a entry, will remove it.

There is a built in remove(index) ability you can also use to remove array entries too, which this function actually uses.

However for that you need to provide the index number, while there may be instances where you want to remove an entry by it's actual data instead.

To install.
copy & paste the following code into the Global Functions panel of Game Configuration in your project.

function clear_entry($array, $entry) begin
	$index = 0;
	for $i in $array do
		if $i == $entry then
			$array.remove($index);
			break;
		end;
		$index += 1;
	end;
end;

To use,
simply call the function and provide the array to search, and the data to search for.

Example:

By default, this function will find and delete the first entry it finds that matches the provided data, and then stop.
If you wish to find and remove all entries that match the provided data, simply replace break; from the function code with $index -= 1;.

The result would be something like this:

COUNT ITEMS

This function will scan your inventory for a provided item and return how many items matching the request are found.
It does not matter if items are stackable in a single slot, or repeated in different slots, it will find all instances and add them into a final total, which is then returned into a variable in a main script.

To Install:
copy & paste the following code into the Global Functions panel of Game Configuration in your project.

function count_items($item_id) begin
	$slot_num = 0;
	$itm_count = 0;
	for $i in player.inventory do 
		$slot_num += 1;
		if $slot_num < 10 then
			if widget["inventory"].element["000${$slot_num}"].item != null then
				$itm = widget["inventory"].element["000${$slot_num}"].item;
				if $itm.id == $item_id then
					$itm_count += widget["inventory"].element["000${$slot_num}"].item.count;
				end;
			end;
		else
			if widget["inventory"].element["00${$slot_num}"].item != null then
				$itm = widget["inventory"].element["00${$slot_num}"].item;
				if $itm.id == $item_id then
					$itm_count += widget["inventory"].element["00${$slot_num}"].item.count;
				end;
			end;            
		end;
	end;
	return $itm_count;
end;

IMPORTANT NOTE:
If you are using a custom inventory widget in your project, you will need to alter the widget["inventory"] parts of the function, replacing "inventory" with the ID of your custom widget.

To Use:
Simply call the function into a variable in a script when necessary, and provide an item id of the item you wish to search the inventory for.

Example:

CUSTOM USE

This is the function from my recent Free Movement Interaction video.

This function provides an alternate way of interacting with objects and characters in Free Movement if you are experiencing issues with the collision based system.

This function will check all four tiles immediately around the player's tile at the time of execution (usually a keybind) in all four directions (north_tile, south_tile, west_tile, east_tile), store any characters and objects found in that radius, check the player's camera direction and then if in the direction of a valid object/character, will trigger a remote interact of the entity, using the extremely useful new (V1.1) interact_with_entity() command.

Few things to note:
This function prioritises Characters above Objects if both are found on the same tile.
If you wish to swap that, then check for object first, then else, check for character.
If you want to trigger both, then you could check if both are valid, then interact_with_entity character followed by object.

Also:
NAVIGATION REQUIRED!
For this function to work, although in Free Movement, the player no longer needs the navigation lines, for the north_tile, east_tile process to work, all tiles should be linked up in some fashion on the navigation grid.
Pending can be used as an alternative to none functionality wise.

To install, somply copy pase the following code into the Game Configuration > Global Functions panel.

function custom_use() begin
	$player_tile = tile[player.coord.x, player.coord.y, player.coord.z];
	if $player_tile.north_tile.objects != null then
		$north_object = $player_tile.north_tile.objects[0];
	end;
	if $player_tile.east_tile.objects != null then
		$east_object = $player_tile.east_tile.objects[0];
	end;
	if $player_tile.south_tile.objects != null then
		$south_object = $player_tile.south_tile.objects[0];
	end;
	if $player_tile.west_tile.objects != null then
		$west_object = $player_tile.west_tile.objects[0];
	end;
	if $player_tile.north_tile.characters != null then
	     $north_character = $player_tile.north_tile.characters[0];
	end;
	if $player_tile.east_tile.characters != null then
		$east_character = $player_tile.east_tile.characters[0];
	end;
	if $player_tile.south_tile.characters != null then
		$south_character = $player_tile.south_tile.characters[0];
	end;
	if $player_tile.west_tile.characters != null then
		$west_character = $player_tile.west_tile.characters[0];
	end;
	if player.direction == NORTH then
		if $north_character != null then
			interact_with_entity($north_character);
		else
			if $north_object != null then
				interact_with_entity($north_object);
			end;
		end;
	elseif player.direction == EAST then
		if $east_character != null then
			interact_with_entity($east_character);
		else
			if $east_object != null then
				interact_with_entity($east_object);
			end;
		end;
	elseif player.direction == SOUTH then
		if $south_character != null then
			interact_with_entity($south_character);
		else
			if $south_object != null then
				interact_with_entity($south_object);
			end;
		end;
	elseif player.direction == WEST then
		if $west_character != null then
			interact_with_entity($west_character);
		else
			if $west_object != null then
				interact_with_entity($west_object);
			end;
		end;
	end;
end;

To use, make a script and add the following code to it to call the function.

custom_use();

Feel free to bind this script over the top of the base interact key, or to another key to benefit from both interaction styles.