LuckyBoyAK
You mean how I made the Quest Log?
To be honest: It was done rather in a makeshift way.

An open book is composed of 4 widgets:

At the bottom (i.e., called first) is a large, screen-filling, invisible button that runs a script to close the book.
Then there is a widget without pass-through, containing the graphic of the book.
Next comes a widget with the corresponding text labels (one for the title, then the first page and the second page). These are filled using a global variable.
On top (i.e., called last), there's a widget with two large buttons for turning pages forward and backward. These are also invisible (achieved by setting the appropriate WidgetTheme).

Before I call all 4 widgets, I fill the global variables, and if the book only has one page, I simply omit the last widget.

This method actually works quite well for me. However, you lose the ability to move the widgets around. So they are statically positioned at the center of the screen.

I call it like this:

   widget["book0"].element["0001"].image = "openerionbook.png";

    $currentquest = global.property["currentquest"];
    $numberofquests = len(player.quests);

    if $currentquest < 1 then
        $currentquest = 1;
    elseif $currentquest > $numberofquests then
        $currentquest = $numberofquests;
    end;

    $currentquestid = player.quests[$currentquest - 1];
    $questtext = $currentquestid + "_text";

    if global.property[$questtext] == null then
        global.property[$questtext] = quest[$currentquestid].description;
    end;

    global.property["currentquestname"] = quest[$currentquestid].name;
    global.property["currentquestdesc"] = global.property[$questtext];
    global.property["booktext"] = global.property[$questtext];
    global.property["booktitle"] = "Quest Log";
    global.property["pagetitle"] = quest[$currentquestid].name;
    global.property["currentquestpage"] = $currentquest + " / " + $numberofquests;
    global.property["currentquest"] = $currentquest;
    global.property["bookpages"] = str($currentquest + " / " + $numberofquests);
    global.property["numberofpages"] = $numberofquests;
    $booktext = global.property["booktext"];
    $firstPageLines = 16;
    $otherPagesLines = 18;
    $PageLineLength = 30;
    $firstPageMaxLength = $firstPageLines * $PageLineLength;
    $otherPagesMaxLength = $otherPagesLines * $PageLineLength;
    $pageIndex = 1;
    $pageStart = 0;
    
    while $pageStart < len($booktext) do
        $remainingCharacters = len($booktext) - $pageStart;
    
        if $pageIndex == 1 then
            $maxPageLength = $firstPageMaxLength;
        else
            $maxPageLength = $otherPagesMaxLength;
        end;
    
        if $remainingCharacters > $maxPageLength then
            $pageEnd = $pageStart + $maxPageLength;
            while $pageEnd > $pageStart and substr($booktext, $pageEnd, 1) != " " do
                $pageEnd -= 1;
            end;
        else
            $pageEnd = $pageStart + $remainingCharacters;
        end;
    
        global.property["page" + $pageIndex] = "[color=#2a2a45]" + substr($booktext, $pageStart, $pageEnd - $pageStart) + " [/color]";
        $pageIndex += 1;
        $pageStart = $pageEnd + 1;
    end;
    
    global.property["pagetitle"] = "[color=#2a2a45]" + global.property["pagetitle"] + " [/color]";
    global.property["bookpages"] = "[color=#2a2a45]" + global.property["bookpages"] + " [/color]";
    
    if global.property["_journal_"] == true or global.property["_questlog_"] == true then
show_widget("book1");
    else
        show_widget("book2");
    end;
    
    if global.property["numberofpages"] != null and global.property["numberofpages"] > 1 then 
        if global.property["_questlog_"] == true then
            widget["book_Overlay"].element["0005"].script = "__nextquest__";
            widget["book_Overlay"].element["0006"].script = "__prevquest__";
        else
            widget["book_Overlay"].element["0005"].script = "null";
            widget["book_Overlay"].element["0006"].script = "null";
        end;
        show_widget("book_Overlay");
    end;